【BAT批处理】bat批量处理脚本常用命令

【BAT批处理】bat批量处理脚本常用命令

五、常用命令

1、ECHO，显示及关闭回显，输出信息及空行。

@echo on ：打开回显，显示执行脚本的命令内容。
@echo off ：关闭回显
echo message：输出消息message
echo：后面不接内容，表示输出空行。

2、PAUSE，暂停批处理程序，并显示以下消息:请按任意键继续. . .

此命令不再做描述，如标题所示。 

3、CLS，清除屏幕。

此命令不再做描述，如标题所示。 

4、REM

在批处理文件或 CONFIG.SYS 里加上注解或说明。

REM [comment]

这个命令同样没什么好说的,用法就是rem 注释

PS:其实可以用"::"代替"REM",可以提高执行速度,不过REM的兼容性更好,我还是建议大家用rem注释

5、SET

1）给变量赋值(撤销)

例1：

@echo off
set str=My name is Xiao
rem 批处理脚本中用%或！来表示扩展
echo %str%
rem pause默认输出信息为"请按任意键继续"，也可以自定义输出，例如pause>nul
pause>nul

例2：

@echo off
set str=ABCDEFGHIJKLMN
echo %str%
set str=
rem 还记得加";"，这里的分号";"必须跟echo不能有空格，作用是打开前面已经关闭的回显，并且输出变量；否则不输出变量且输出提示“ECHO 处于关闭状态。”
echo;%str%
pause>nul

上面的例子中,一个是给变量赋值,一个是撤销变量的值

2）等待用户输入数据(开关/P)

例：　

@echo off
set /p name=请输入你的姓名:
set /p age=请输入你的年龄(纯数字):
echo 所以,%name%今年%age%岁咯?
pause>nul

3）计算(开关/A)

set /a支持多行表达式并列,比如set /a num1=1+1,num2=1+2,num3=1+3

并且set /a不需要扩展变量,比如set /a num=%num2%+%num3%与set /a num=num2+num3等价

例1：

@echo off
set /a num=(12*2)+(13*4)
echo (12x2)+(13x4)=%num%
pause>nul

例2：

@echo off
set /p num=请输入一个数字(不要超过2147483647):
REM 批处理能处理的数字不能超过32位(二进制)
set /a num*=2
echo 这个数字的两倍是%num%
pause>nul

附:Set /a num*=2与set /a num=num*2等价

------符号说明-----

() - 分组
! ~ - - 一元运算符
* / % - 算数运算符
+ - - 算数运算符
<< >> - 逻辑移位
- 按位“与”
^ - 按位“异”
| - 按位“或”
= *= /= %= += -= - 赋值
&= ^= |= <<= >>=
, - 表达式分隔符

4）显示当前已定义变量

例:

@set
@pause>nul

是不是很简单?其实它还有更高级的用法呢

@set a
@pause>nul
@set s
@pause>nul

它的用法就是这些。

6、IF

1）IF的第一种用法,比较字符串

例:

set /p PW=请输入密码:
if %PW%==bat (
echo YES!　
) ELSE (
Rem [else] 为可选参数,表示否则,即如果变量PW等于bat则输出YES!否则输出NO!　
echo NO!　
)
pause>nul

通过set /p和if可以实现一个简单的密码判断,当然这个密码判断可以很轻易地被破解,仔细动脑筋想一想,该怎么破解呢.

不过这个密码判断尚有不足之处,假如我们什么都不输入直接回车,便会提示错误,那该怎么办呢?很简单,只要加上双引号(其它的符号也行)就行了=>if "%PW%"=="bat"

2）IF的第二种用法,比较数字

例:

set /p num1=请第一个输入数字:
set /p num2=请第二个输入数字:
if not %num1% LSS %num2% (
rem lss表示小于　　
rem [not]为可选参数,表示非,即如果变量num1不小于变量num2就输出第一个数字大,否则输出第二个数字大
echo 第一个数字大
) ELSE (
echo 第二个数字大　　
)
pause>nul

这段代码可以实现一个简单的判断，如果这两个数字相等呢,这就要用到 else if 啦(当然也可以用几个if来判断)

------比较运算符说明-----

EQU - 等于

NEQ - 不等于

LSS - 小于

LEQ - 小于或等于

GTR - 大于

GEQ - 大于或等于

3）IF的第三种用法,检测文件(夹)是否存在

例：

@echo off
if exist C:windows (
echo 你的C盘有windows文件(夹^)
　　
) else (
echo 你的C盘没有windows文件(夹^)
)
pause>nul

"^"为转义符号,在特殊符号一节再作讲解

4）IF的第四种用法，检测变量是否被定义

例：

@echo off
set var=aiwozhonghua
if defined var (
echo 变量var已被定义,它的值为%var%　　
) else (
echo 变量var没有被定义　　
)
pause>nul

尝试：去掉第一行的set看看执行结果有什么不同?

5）IF的第五种用法,判断返回值(ERRORLEVEL)

要判断返回值，首先要理解返回值是个什么概念，批处理中的返回值一般表示了上个命令的执行结果(成功/失败/等)

每个命令执行完毕后返回值都会做相应的更改，一般返回值为0表示成功，1表示失败，有一些第三方的返回值比较特殊(如Choice。exe,Tmos。exe,Cmos。exe)，在这里就不讲解了

例：

@echo off
echo;>>%systemroot%	est.txt
if errorlevel 0 ( echo 写入成功! ) else echo 写入失败
pause>nul

这段代码尝试向

%systemroot%system32

写入数据，如果权限不够或杀毒软件拦截就会写入失败，这时就会显示"写入失败"，不知道

%systemroot%

表示了什么?单独键入set自己仔细看一下结果。

不过看到后面会发现这段代码还有更简便的写法

注：用 if errorlevel判断返回值时要将返回值从大到小排列

例:

@echo off
choice /C:ABC /n "A/B/C"
if errorlevel 3 echo You choose the C
if errorlevel 2 echo You choose the B
if errorlevel 1 echo You choose the A
pause>nul


GOTO 将 cmd。exe 导向到批处理程序中带标签的行。
GOTO label
label 指定批处理程序中用作标签的文字字符串。

6）goto及lable

标签必须单独一行，并且以冒号打头。

如果命令扩展名被启用，GOTO 会如下改变：

GOTO 命令现在接受目标标签 :EOF，这个标签将控制转移到当前批脚本文件的结尾。

不定义就退出批脚本文件，这是一个容易的办法。有关能使该功能有用的 CALL 命令的扩展名描述，请键入CALL /?。

label是什么?这可不是命令label,它指的是标签,标签是啥?见例子。

例：

@echo off
set /p pw=请输入密码:
if "%pw%"=="bathome" goto yes
goto :eof
rem 未定义的:eof会退出脚本文件
:yes
echo 密码正确!
pause>nul

这是一个更加完整的密码判断，仔细阅读并执行这行代码，那个:yes就是标签了!

标签的格式

:标签名

关掉回显以后，标签所在的那一行没有被执行，这就是为什么::比rem更快的原因了，但是标签不能被使用在一个语句的内部，主要就是被括号括起来的语句(是的，被括号括起来的语句被看作一个整体)，因此::的兼容性没有rem那么好

附:"::"其实就是不规范的标签名...

7、FOR

1）FOR

对一组文件中的每一个文件执行某个特定命令。

FOR%variableIN (set) DO command [command-parameters]
%variable 指定一个单一字母可替换的参数。
(set) 指定一个或一组文件。可以使用通配符。
command 指定对每个文件执行的命令。
command-parameters

为特定命令指定参数或命令行开关。

例：

@echo off
E:
cd 工 作\003 脚本命令
for %%i in (*.sql) do echo %%i
pause>nul

这段代码会显示当前文件夹下所有的sql文件

@echo off
for %%i in (菜 芽 小 公 公) do echo %%i
pause>nul

　　这段代码会显示

菜

芽

小

公

公

注：%%i为for输出专用变量格式,其中i可以是a/A/0-z/Z/9和一些符号什么的(如! # 不过不建议使用),在cmd中只能用一个%

2）FOR /L 

FOR /L %variable IN (start,step,end) DO command [command-parameters]

该集表示以增量形式从开始到结束的一个数字序列。

因此，(1,1,5) 将产生序列 1 2 3 4 5，(5,-1,1) 将产生

序列 (5 4 3 2 1)。

例：

@echo off
for /L %%a in (1 2 1000) do echo %%a
pause>nul

输出1到1000之间的整数，间隔为2.

3）FOR /R

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

检查以 [drive:]path 为根的目录树，指向每个目录中的。

FOR 语句。如果在 /R 后没有指定目录，则使用当前目录。

如果集仅为一个单点(.)字符，则枚举该目录树。

例：

@echo off
for /r F:\Store\工作 %%i in (*) do echo %%i
pause>nul

枚举显示F:\Store\工作 目录下的所有目录及文件夹，包括子文件夹里的。

4）FOR /D

FOR /D %variable IN (set) DO command [command-parameters]

如果集中包含通配符，则指定与目录名匹配，而不与文件名匹配。

5）FOR /F 

for /f是一个非(丧)常(心)复(病)杂(狂)的命令...

让我们从它的第一个用法来讲:

FOR /F ["options"] %variable IN (file-set) DO command [command-parame

例:

@echo off
echo 1,1 2,1 3,1 4,1>>test.txt
echo A1,2 2,2 3,2 4,2>>test.txt
echo 1,3 2,3 3,3 4,3>>test.txt
echo A1,4 2,4 3,4 4,4>>test.txt
rem 以上代码在当前文件夹下生成了一个test.txt,打开看看?
For /F %%i In (test.txt) Do Echo %%i
pause>nul
For /F "tokens=2" %%i In (test.txt) Do Echo %%i
pause>nul
For /F "tokens=3" %%i In (test.txt) Do Echo %%i
pause>nul
For /F "tokens=4" %%i In (test.txt) Do Echo %%i
pause>nul

想执行完这个bat，再分析一下结果和代码，这样就了解了tokens的用处

for /f 默认以空格为分隔符，将每一行分割为几个元素，而tokens就表示取第几个元素，但假如我们要取的不是一个元素呢?需要全部显示出来怎么办?

tokens=* 表示取所有元素,用%%i输出

tokens=1,2,3,4或tokens=1-4 然后用%%i或%%i,%%j,%%k,%%l 输出

其实我们还有其他的方法,比如请出delims参数

例：

@echo off
rem test.txt已经有了,就不生成了
for /f "delims=*" %%i in (test.txt) do echo %%i
pause>nul

delims是个什么？其实这就是分割符的设定，默认以空格为分隔符，可以将分隔符设置成其他的，文本就不会被分割了，delims同样支持多个分隔符，格式delims=第一个分隔符，第二个分隔符，第三个分隔符。

还有一个skip和eol，skip表示忽略前几行，比如skip=10表示忽略这个文本的前十行，这个文本只有4行，如果加上skip=10的话就什么都不会输出了

eol表示忽略以某个符号开头的行，比如eol=A，当某一行的开头是A的时候，这一行就不会被处理,不过支持设置一个符号。

for /f同也可以处理字符串

FOR /F ["options"] %variable IN ("string") DO command [command-parameters]

字符串需要用双引号引起来，其余用法一样，不过这里就要讲到usebackq参数了，for /f是支持处理多个文件的，文件直接用空格隔开(某些符号也可以)，假如文件名中含有空格怎么办呢?那好像只能用双引号引起来了，但是用双引号引起来会被识别成字符串的，这时就要请出usebackq参数了，加上这个参数，带引号的字符串也会被识别为文件~

FOR /F ["options"] %variable IN (\'command\') DO command [command-parameters]

用for /f来处理命令执行的结果,命令要用单引号引起来

例:

@echo off
for /f "skip=3" %%i in (\'tasklist\') do echo;%%i
pause>nul

这段代码就处理了命令ipconfig的执行结果，单独键入tasklist看会出现什么?

=======符号说明：=========

~I - 删除任何引号(")，扩充 %I

%~fI - 将 %I 扩充到一个完全合格的路径名

%~dI - 仅将 %I 扩充到一个驱动器号

%~pI - 仅将 %I 扩充到一个路径

%~nI - 仅将 %I 扩充到一个文件名

%~xI - 仅将 %I 扩充到一个文件扩展名

%~sI - 扩充的路径只含有短名

%~aI - 将 %I 扩充到文件的文件属性

%~tI - 将 %I 扩充到文件的日期/时间

%~zI - 将 %I 扩充到文件的大小

%~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩充

到找到的第一个完全合格的名称。如果环境变量名

未被定义，或者没有找到文件，此组合键会扩充到

空字符串

组合修饰符来得到多重结果:

%~dpI - 仅将 %I 扩充到一个驱动器号和路径

%~nxI - 仅将 %I 扩充到一个文件名和扩展名

%~fsI - 仅将 %I 扩充到一个带有短名的完整路径名

%~dp$PATH:i - 查找列在路径环境变量的目录，并将 %I 扩充

到找到的第一个驱动器号和路径。

%~ftzaI - 将 %I 扩充到类似输出线路的 DIR

===================================================

用for /r命令输出的时候把%%i改成%%~nxi之类的试一试，就能理解这代码。

8、其他命令

批处理的常见命令（未列举的命令还比较多，请查阅帮助信息）

1、REM 和 ::

2、ECHO 和 @

3、PAUSE

4、ERRORLEVEL

5、TITLE

6、COLOR

7、mode 配置系统设备

8、GOTO 和 :

9、FIND

10、START

11、assoc 和 ftype

12、pushd 和 popd

13、CALL

14、shift

15、IF

16、setlocal 与 变量延迟

17、ATTRIB 显示或更改文件属性